{-# LANGUAGE LambdaCase #-}

{-

Docs:

- EZConfig: https://hackage.haskell.org/package/xmonad-contrib-0.13/docs/XMonad-Util-EZConfig.html#g:3
- Media keys: https://hackage.haskell.org/package/X11-1.9/docs/Graphics-X11-ExtraTypes-XF86.html
- Audio control: https://xmonadhaskell.wordpress.com/2018/10/24/xmonad-audio-control/

- XMonad API: https://hackage.haskell.org/package/xmonad
- Contrib API: https://hackage.haskell.org/package/xmonad-contrib

Inspirations:

- https://reddit.simatime.com/wy695w

-}

import Data.Functor ((<&>))
import Data.List (intercalate, isPrefixOf)
import Graphics.X11.ExtraTypes.XF86
import XMonad
import XMonad.Actions.CopyWindow
import XMonad.Config
import XMonad.Config.Desktop
import XMonad.Hooks.EwmhDesktops (ewmh)
import XMonad.Hooks.ManageDocks
import XMonad.Hooks.ManageHelpers (doFullFloat, isFullscreen)
import XMonad.Layout.BinarySpacePartition
import XMonad.Layout.Dwindle as Dwindle
import XMonad.Layout.LayoutModifier
import XMonad.Layout.NoBorders
import XMonad.Layout.ResizableTile
import XMonad.Layout.Spacing
import XMonad.Layout.Spiral
import XMonad.Layout.Tabbed
import XMonad.Layout.ThreeColumns
import XMonad.Layout.TwoPane
import qualified XMonad.StackSet as W
import XMonad.Util.CustomKeys (customKeys)
import XMonad.Util.EZConfig (additionalKeys)
import XMonad.Util.NamedScratchpad

-- Colors
data Colors = Colors
  { foreground :: String,
    background :: String,
    highlight :: String
  }

lightTheme =
  Colors
    { highlight = "#67b11d",
      background = "#f6f1e1",
      foreground = "#655370"
    }

darkTheme =
  Colors
    { highlight = "#5d4d7a",
      background = "#292b2e",
      foreground = "#b2b2b2"
    }

getColorsFromXtheme :: IO Colors
getColorsFromXtheme =
  readFile "/home/ben/.local/share/xtheme"
    <&> filter (/= '\n')
    >>= \case
      "light" -> return lightTheme
      "dark" -> return darkTheme
      _ -> return darkTheme

altMask :: KeyMask
altMask = mod1Mask

brighter = "brightnessctl s 5%+"

dimmer = "brightnessctl s 5%-"

shouldntFloat :: String -> Bool
shouldntFloat = isPrefixOf "qutebrowser"

shouldFloat :: Query Bool
shouldFloat = do
  fs <- isFullscreen
  name <- appName
  return (fs && not (shouldntFloat name))

-- RationalRect is x y w h
scratchHook = namedScratchpadManageHook scratchpads --

myManageHook = manageDocks <+> scratchHook <+> (shouldFloat --> doFullFloat) <+> manageHook def

-- todo: use urxvtc with daemon
termName = "/home/ben/.nix-profile/bin/urxvt"

centerFloat = customFloating (W.RationalRect 0.125 0.125 0.75 0.75)

scratchpads = [
    -- run htop in xterm, find it by title
    NS "htop" "urxvt -e htop" (title =? "htop") centerFloat,
    NS "gotop" "urxvt -e gotop" (title =? "gotop") centerFloat,

    NS "nvtop" "urxvt -e nvtop" (title =? "nvtop") centerFloat,

    NS "pavucontrol" "pavucontrol" (className =? "Pavucontrol") centerFloat
  ]

insKeys :: XConfig l -> [((KeyMask, KeySym), X ())]
insKeys conf@(XConfig {modMask = modMask}) =
  [ ((modMask, xK_y), spawn "passmenu"),
    ((modMask, xK_m), spawn "cmdtree"),
    ((modMask, xK_o), spawn "rofi -sidebar-mode -show run"),
    ((modMask, xK_n), spawn "rofi -sidebar-mode -show window"),
    ((modMask, xK_u), spawn "rofi -show calc -modi calc -no-show-match -no-sort"),

    -- scratchpads
    ((modMask .|. shiftMask, xK_h), namedScratchpadAction scratchpads "htop"),
    ((modMask .|. shiftMask, xK_g), namedScratchpadAction scratchpads "gotop"),
    ((modMask .|. shiftMask, xK_n), namedScratchpadAction scratchpads "nvtop"),
    ((modMask .|. shiftMask, xK_p), namedScratchpadAction scratchpads "pavucontrol"),

    -- refresh display via autorandr
    ( (modMask, xK_r),
      spawn $ "autorandr --cycle"
    ),
    -- lock it up
    ((modMask .|. shiftMask, xK_l), spawn "xautolock -locknow"),
    -- sticky windows
    ((modMask, xK_a), windows copyToAll), -- @@ Make focused window always visible
    ((modMask .|. shiftMask, xK_a), killAllOtherCopies), -- @@ Toggle window state back

    -- media/ function keys
    -- backlight
    ((0, xF86XK_MonBrightnessDown), spawn dimmer),
    ((0, xF86XK_MonBrightnessUp), spawn brighter),
    -- volume controls
    ((0, xF86XK_AudioMute), amixer "toggle"),
    ((0, xF86XK_AudioLowerVolume), amixer "2%-"),
    ((0, xF86XK_AudioRaiseVolume), amixer "2%+")
  ]

amixer :: String -> X ()
amixer cmd = spawn $ "amixer -q sset Master " <> cmd

-- | Golden-ratio spiral
goldenSpiral :: SpiralWithDir a
goldenSpiral = spiral (6 / 7)

myWorkspaces :: [String]
myWorkspaces = ["1[org]", "2[dev]", "3[chat]", "4[lithium]", "5[mon]", "6", "7", "8", "9"]

addSpace :: l a -> ModifiedLayout Spacing l a
addSpace =
  spacingRaw
    False
    (Border 5 5 5 5)
    True
    (Border 5 5 5 5)
    True

myTabCfg theme =
  def
    { fontName = "xft:Fira Sans:size=10:ant",
      activeBorderColor = highlight theme,
      inactiveBorderColor = background theme,
      activeColor = highlight theme,
      inactiveColor = background theme
    }

myLayout theme =
  avoidStruts $
    noBorders (tabbed shrinkText $ myTabCfg theme)
      ||| (addSpace $ noBorders Full)
      ||| twopane
      ||| Mirror twopane
      ||| ThreeCol 1 (3 / 100) (1 / 2)
      ||| ThreeColMid 1 (3 / 100) (1 / 2)
      ||| tiled
      ||| Mirror tiled
      ||| emptyBSP
  where
    --      ||| goldenSpiral
    --      ||| Spiral R Dwindle.CW (3 / 2) (11 / 10) -- L/R is where to put non-main windows

    -- The last parameter is fraction to multiply the slave window heights
    -- with. Useless here.
    tiled = addSpace $ ResizableTall nmaster delta ratio []
    -- The default number of windows in the master pane
    nmaster = 1
    -- In this layout the second pane will only show the focused window.
    twopane = addSpace $ TwoPane delta ratio
    -- Default proportion of screen occupied by master pane
    ratio = 1 / 2
    -- Percent of screen to increment by when resizing panes
    delta = 3 / 100


myConf theme = additionalKeys cfg (insKeys cfg)
  where
    cfg =
      desktopConfig
        { modMask = mod4Mask, -- super instead of alt
          normalBorderColor = background theme,
          focusedBorderColor = highlight theme,
          borderWidth = 3,
          manageHook = myManageHook,
          layoutHook = myLayout theme,
          terminal = termName,
          workspaces = myWorkspaces
        }

main :: IO ()
main = do
  theme <- getColorsFromXtheme
  xmonad $ ewmh $ docks $ myConf theme