Re-namespace some stuff to Omni

I was getting confused about what is a product and what is internal
infrastructure; I think it is good to keep those things separate. So I moved a
bunch of stuff to an Omni namespace, actually most stuff went there. Only things
that are explicitly external products are still in the Biz namespace.

1 files changed, 56 insertions, 0 deletions

diff --git a/Omni/Id.hs b/Omni/Id.hs
new file mode 100644
index 0000000..59201d5
--- /dev/null
+++ b/Omni/Id.hs
@@ -0,0 +1,56 @@
+{-# LANGUAGE DeriveDataTypeable #-}
+{-# LANGUAGE DeriveGeneric #-}
+{-# LANGUAGE NoImplicitPrelude #-}
+
+-- Integer-based identifier.
+module Omni.Id
+  ( Id (..),
+    mk,
+    untag,
+  )
+where
+
+import Alpha
+import Data.Aeson (FromJSON (..), ToJSON (..))
+import Data.Binary (Binary)
+import Data.Data (Data)
+import Servant (FromHttpApiData (..), ToHttpApiData (..))
+
+newtype Id entity = Id Int
+  deriving (Eq, Ord, Show, Generic, Typeable, Data)
+
+mk :: proxy entity -> Int -> Id entity
+mk _ = Id
+
+untag :: Id entity -> Int
+untag (Id i) = i
+
+instance Hashable (Id entity)
+
+instance Binary (Id entity)
+
+instance Enum (Id entity) where
+  toEnum = mk (Proxy :: Proxy entity)
+  fromEnum = untag
+
+instance NFData (Id entity) where
+  rnf (Id s) = rnf s
+
+instance FromJSON (Id entity) where
+  parseJSON = fmap Id <. parseJSON
+
+instance ToJSON (Id entity) where
+  toJSON = toJSON <. untag
+
+-- this is just provided to satisfy Monoid, no reason to actually use it
+instance Semigroup (Id entity) where
+  a <> b = mk (Proxy :: Proxy entity) <| untag a + untag b
+
+instance Monoid (Id entity) where
+  mempty = mk (Proxy :: Proxy entity) 0
+
+instance FromHttpApiData (Id entity) where
+  parseUrlPiece p = mk (Proxy :: Proxy entity) </ parseUrlPiece p
+
+instance ToHttpApiData (Id entity) where
+  toUrlPiece p = untag p |> tshow