Omni/Bild/Nixpkgs.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

let
  sources = import ./Sources.nix { sourcesFile = ./Sources.json; };

  config = {
    allowAliases = true;
    allowBroken = true;
    allowUnfree = true;
    checkMeta = true;
    cudaSupport = true;
  };

  system = __currentSystem;

  # override pinned deps with our sources, this must come before other
  # package overlays, because of the 'null' from 'overrideSource'
  depsOverlay = _: pkgs: pkgs.overridePinnedDeps pkgs.overrideSource;

  overlays = [
    (_: _: { inherit sources; })
    (import ./CcacheWrapper.nix)
    (import ./Functions.nix)
    depsOverlay
    (import ./Deps.nix)
    (import ./Python.nix)
    (import ./Haskell.nix)
    # backport newer packages from unstable
    (_: _: { unstable = nixos-unstable-small.pkgs; })
  ];

  nixos-unstable-small =
    import sources.nixos-unstable-small { inherit system config overlays; };

in {
  nixos-24_05 = import sources.nixos-24_05 { inherit system config overlays; };

  nixos-24_11 = import sources.nixos-24_11 { inherit system config overlays; };

  inherit nixos-unstable-small;
}